mirror of
https://github.com/realAscot/helix.git
synced 2025-09-14 04:03:03 +02:00
05ae617e1c
This fixes injections of Slint and HTML in Rust macros. These patterns must be moved after the generic `(macro_invocation (token_tree))` pattern since they are more specific, and later patterns now take priority. See <https://redirect.github.com/helix-editor/helix/pull/12972#issuecomment-2888300442>.
100 lines
3.0 KiB
Scheme
100 lines
3.0 KiB
Scheme
([(line_comment !doc) (block_comment !doc)] @injection.content
|
|
(#set! injection.language "comment"))
|
|
|
|
((doc_comment) @injection.content
|
|
(#set! injection.language "markdown-rustdoc")
|
|
(#set! injection.combined))
|
|
|
|
((macro_invocation
|
|
(token_tree) @injection.content)
|
|
(#set! injection.language "rust")
|
|
(#set! injection.include-children))
|
|
|
|
((macro_rule
|
|
(token_tree) @injection.content)
|
|
(#set! injection.language "rust")
|
|
(#set! injection.include-children))
|
|
|
|
((macro_invocation
|
|
macro:
|
|
[
|
|
(scoped_identifier
|
|
name: (_) @_macro_name)
|
|
(identifier) @_macro_name
|
|
]
|
|
(token_tree) @injection.content)
|
|
(#eq? @_macro_name "html")
|
|
(#set! injection.language "html")
|
|
(#set! injection.include-children))
|
|
|
|
((macro_invocation
|
|
macro:
|
|
[
|
|
(scoped_identifier
|
|
name: (_) @_macro_name)
|
|
(identifier) @_macro_name
|
|
]
|
|
(token_tree) @injection.content)
|
|
(#eq? @_macro_name "slint")
|
|
(#set! injection.language "slint")
|
|
(#set! injection.include-children))
|
|
|
|
((macro_invocation
|
|
macro:
|
|
[
|
|
(scoped_identifier name: (_) @_macro_name)
|
|
(identifier) @_macro_name
|
|
]
|
|
(token_tree
|
|
(token_tree . "{" "}" .) @injection.content))
|
|
(#eq? @_macro_name "json")
|
|
(#set! injection.language "json")
|
|
(#set! injection.include-children))
|
|
|
|
(call_expression
|
|
function: (scoped_identifier
|
|
path: (identifier) @_regex (#any-of? @_regex "Regex" "RegexBuilder")
|
|
name: (identifier) @_new (#eq? @_new "new"))
|
|
arguments: (arguments (raw_string_literal (string_content) @injection.content))
|
|
(#set! injection.language "regex"))
|
|
|
|
(call_expression
|
|
function: (scoped_identifier
|
|
path: (scoped_identifier (identifier) @_regex (#any-of? @_regex "Regex" "RegexBuilder") .)
|
|
name: (identifier) @_new (#eq? @_new "new"))
|
|
arguments: (arguments (raw_string_literal (string_content) @injection.content))
|
|
(#set! injection.language "regex"))
|
|
|
|
; Highlight SQL in `sqlx::query!()`, `sqlx::query_scalar!()`, and `sqlx::query_scalar_unchecked!()`
|
|
(macro_invocation
|
|
macro: (scoped_identifier
|
|
path: (identifier) @_sqlx (#eq? @_sqlx "sqlx")
|
|
name: (identifier) @_query (#match? @_query "^query(_scalar|_scalar_unchecked)?$"))
|
|
(token_tree
|
|
; Only the first argument is SQL
|
|
.
|
|
[
|
|
(string_literal (string_content) @injection.content)
|
|
(raw_string_literal (string_content) @injection.content)
|
|
]
|
|
)
|
|
(#set! injection.language "sql"))
|
|
|
|
; Highlight SQL in `sqlx::query_as!()` and `sqlx::query_as_unchecked!()`
|
|
(macro_invocation
|
|
macro: (scoped_identifier
|
|
path: (identifier) @_sqlx (#eq? @_sqlx "sqlx")
|
|
name: (identifier) @_query_as (#match? @_query_as "^query_as(_unchecked)?$"))
|
|
(token_tree
|
|
; Only the second argument is SQL
|
|
.
|
|
; Allow anything as the first argument in case the user has lower case type
|
|
; names for some reason
|
|
(_)
|
|
[
|
|
(string_literal (string_content) @injection.content)
|
|
(raw_string_literal (string_content) @injection.content)
|
|
]
|
|
)
|
|
(#set! injection.language "sql"))
|